//+------------------------------------------------------------------+
//| Heiken Ashi Ma T3.mq4 |
//+------------------------------------------------------------------+
//| mod by Raff |
//| 2009 mod by mladen |
//+------------------------------------------------------------------+
#property copyright "Copyright � 2008,Forex-TSD.com"
#property link "http://www.forex-tsd.com/"
#property indicator_separate_window
#property indicator_buffers 6
#property indicator_color1 Red
#property indicator_color2 RoyalBlue
#property indicator_color3 Red
#property indicator_color4 RoyalBlue
#property indicator_color5 Aqua
#property indicator_color6 Magenta
#property indicator_width1 1
#property indicator_width2 1
#property indicator_width3 2
#property indicator_width4 2
#property indicator_width5 1
#property indicator_width6 1
//
//
//
//
//
extern string TimeFrame = "Current time frame";
extern int MaPeriod = 10;
extern int MaMetod = 2;
extern int Step = 10;
extern bool BetterFormula = false;
extern bool T3Average = true;
extern double T3Hot = 0.618;
extern bool T3Original = false;
extern string BarsID = "HA separate 1";
extern color ColorUp = RoyalBlue;
extern color ColorDn = Red;
extern int widthWick = 1;
extern int widthBody = 3;
extern bool alertsOn = false;
extern bool alertsOnCurrent = false;
extern bool alertsMessage = true;
extern bool alertsSound = false;
extern bool alertsEmail = false;
//
//
//
//
//
double ExtMapBuffer1[];
double ExtMapBuffer2[];
double ExtMapBuffer3[];
double ExtMapBuffer4[];
double UpArrow[];
double DnArrow[];
//
//
//
//
//
double emas[][24];
double alpha;
double c1;
double c2;
double c3;
double c4;
string indicatorName;
static bool TurnedUp = false;
static bool TurnedDown = false;
datetime timeprev = 0;
int window;
//
//
//
//
//
string indicatorFileName;
bool calculateValue;
bool returnBars;
int timeFrame;
//+------------------------------------------------------------------+
//| |
//|------------------------------------------------------------------|
//
//
//
//
//
int init()
{
SetIndexBuffer(0, ExtMapBuffer1); SetIndexStyle(0,DRAW_NONE);
SetIndexBuffer(1, ExtMapBuffer2); SetIndexStyle(1,DRAW_NONE);
SetIndexBuffer(2, ExtMapBuffer3); SetIndexStyle(2,DRAW_NONE);
SetIndexBuffer(3, ExtMapBuffer4); SetIndexStyle(3,DRAW_NONE);
SetIndexBuffer(4, UpArrow); SetIndexStyle(4,DRAW_ARROW); SetIndexArrow(4,233);
SetIndexBuffer(5, DnArrow); SetIndexStyle(5,DRAW_ARROW); SetIndexArrow(5,234);
//
//
//
//
//
double a = T3Hot;
c1 = -a*a*a;
c2 = 3*(a*a+a*a*a);
c3 = -3*(2*a*a+a+a*a*a);
c4 = 1+3*a+a*a*a+3*a*a;
MaPeriod = MathMax(1,MaPeriod);
if (T3Original)
alpha = 2.0/(1.0 + MaPeriod);
else alpha = 2.0/(2.0 + (MaPeriod-1.0)/2.0);
//
//
//
//
//
indicatorFileName = WindowExpertName();
calculateValue = (TimeFrame=="CalculateValue"); if (calculateValue) return(0);
returnBars = (TimeFrame=="returnBars"); if (returnBars) return(0);
timeFrame = stringToTimeFrame(TimeFrame);
indicatorName=BarsID+" - "+" Heiken Ashi "+MaPeriod;
IndicatorShortName(indicatorName);
return(0);
}
//
//
//
//
//
int deinit()
{
string lookFor = BarsID+":";
int lookForLength = StringLen(lookFor);
for (int i = ObjectsTotal(); i>= 0; i--)
{
string name = ObjectName(i);
if (StringSubstr(name,0,lookForLength)==lookFor) ObjectDelete(name);
}
return (0);
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
//
//
//
//
//
int start()
{
double maOpen, maClose, maLow, maHigh;
double haOpen, haClose, haLow, haHigh;
int counted_bars=IndicatorCounted();
int pointModifier;
int i,limit;
//
//
//
//
//
if(counted_bars<0) return(-1);
if(counted_bars>0) counted_bars--;
limit = Bars-counted_bars;
if (returnBars) { ExtMapBuffer1[0] = limit+1; return(0); }
window = WindowFind(indicatorName);
//
//
//
//
//
if (calculateValue || timeFrame == Period())
{
if(timeprev<iTime(NULL,0,0)) {TurnedDown=false; TurnedUp=false;timeprev=iTime(NULL,0,0);}
if (ArrayRange(emas,0) != Bars) ArrayResize(emas,Bars);
if (Digits==3 || Digits==5)
pointModifier = 10;
else pointModifier = 1;
//
//
//
//
//
for(int pos=limit; pos >= 0; pos--)
{
if (T3Average)
{
maOpen = iT3(Open[pos] ,pos, 0);
maClose = iT3(Close[pos],pos, 6);
maLow = iT3(Low[pos] ,pos,12);
maHigh = iT3(High[pos] ,pos,18);
}
else
{
maOpen = iMA(NULL,0,MaPeriod,0,MaMetod,PRICE_OPEN ,pos);
maClose = iMA(NULL,0,MaPeriod,0,MaMetod,PRICE_CLOSE,pos);
maLow = iMA(NULL,0,MaPeriod,0,MaMetod,PRICE_LOW ,pos);
maHigh = iMA(NULL,0,MaPeriod,0,MaMetod,PRICE_HIGH ,pos);
}
//
//
//
//
//
if (BetterFormula) {
if (maHigh!=maLow)
haClose = (maOpen+maClose)/2+(((maClose-maOpen)/(maHigh-maLow))*MathAbs((maClose-maOpen)/2));
else haClose = (maOpen+maClose)/2; }
else haClose = (maOpen+maHigh+maLow+maClose)/4;
haOpen = (ExtMapBuffer3[pos+1]+ExtMapBuffer4[pos+1])/2;
haHigh = MathMax(maHigh, MathMax(haOpen,haClose));
haLow = MathMin(maLow, MathMin(haOpen,haClose));
if (haOpen<haClose) { ExtMapBuffer1[pos]=haLow; ExtMapBuffer2[pos]=haHigh; }
else { ExtMapBuffer1[pos]=haHigh; ExtMapBuffer2[pos]=haLow; }
ExtMapBuffer3[pos]=haOpen;
ExtMapBuffer4[pos]=haClose;
//
//
//
//
//
if (Step>0)
{
if( MathAbs(ExtMapBuffer1[pos]-ExtMapBuffer1[pos+1]) < Step*pointModifier*Point ) ExtMapBuffer1[pos]=ExtMapBuffer1[pos+1];
if( MathAbs(ExtMapBuffer2[pos]-ExtMapBuffer2[pos+1]) < Step*pointModifier*Point ) ExtMapBuffer2[pos]=ExtMapBuffer2[pos+1];
if( MathAbs(ExtMapBuffer3[pos]-ExtMapBuffer3[pos+1]) < Step*pointModifier*Point ) ExtMapBuffer3[pos]=ExtMapBuffer3[pos+1];
if( MathAbs(ExtMapBuffer4[pos]-ExtMapBuffer4[pos+1]) < Step*pointModifier*Point ) ExtMapBuffer4[pos]=ExtMapBuffer4[pos+1];
}
if (!calculateValue) drawBar(Time[pos],ExtMapBuffer1[pos],ExtMapBuffer2[pos],ExtMapBuffer3[pos],ExtMapBuffer4[pos]);
UpArrow[pos]=EMPTY_VALUE;
DnArrow[pos]=EMPTY_VALUE;
if (ExtMapBuffer3[pos]<ExtMapBuffer4[pos] && ExtMapBuffer4[pos+1]<ExtMapBuffer3[pos+1]) UpArrow[pos]=ExtMapBuffer4[pos+1]-iATR(NULL,0,20,i)/2.0;
if (ExtMapBuffer3[pos]>ExtMapBuffer4[pos] && ExtMapBuffer4[pos+1]>ExtMapBuffer3[pos+1]) DnArrow[pos]=ExtMapBuffer4[pos+1]+iATR(NULL,0,20,i)/2.0;
}
manageAlerts();
return(0);
}
//
//
//
//
//
limit = MathMax(limit,MathMin(Bars,iCustom(NULL,timeFrame,indicatorFileName,"returnBars",0,0)*timeFrame/Period()));
for (i=limit;i>=0;i--)
{
int y = iBarShift(NULL,timeFrame,Time[i]);
ExtMapBuffer1[i] = iCustom(NULL,timeFrame,indicatorFileName,"CalculateValue",MaPeriod,MaMetod,Step,BetterFormula,T3Average,T3Hot,T3Original,0,y);
ExtMapBuffer2[i] = iCustom(NULL,timeFrame,indicatorFileName,"CalculateValue",MaPeriod,MaMetod,Step,BetterFormula,T3Average,T3Hot,T3Original,1,y);
ExtMapBuffer3[i] = iCustom(NULL,timeFrame,indicatorFileName,"CalculateValue",MaPeriod,MaMetod,Step,BetterFormula,T3Average,T3Hot,T3Original,2,y);
ExtMapBuffer4[i] = iCustom(NULL,timeFrame,indicatorFileName,"CalculateValue",MaPeriod,MaMetod,Step,BetterFormula,T3Average,T3Hot,T3Original,3,y);
drawBar(Time[i],ExtMapBuffer1[i],ExtMapBuffer2[i],ExtMapBuffer3[i],ExtMapBuffer4[i]);
if (y!=iBarShift(NULL,timeFrame,Time[i+1]))
{
UpArrow[i] = iCustom(NULL,timeFrame,indicatorFileName,"CalculateValue",MaPeriod,MaMetod,Step,BetterFormula,T3Average,T3Hot,T3Original,4,y);
DnArrow[i] = iCustom(NULL,timeFrame,indicatorFileName,"CalculateValue",MaPeriod,MaMetod,Step,BetterFormula,T3Average,T3Hot,T3Original,5,y);
}
}
manageAlerts();
//
//
//
//
//
return(0);
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
//
//
//
//
//
double iT3(double price,int shift,int buffer)
{
int i = Bars-shift-1;
if (i < 1)
{
emas[i][0+buffer] = price;
emas[i][1+buffer] = price;
emas[i][2+buffer] = price;
emas[i][3+buffer] = price;
emas[i][4+buffer] = price;
emas[i][5+buffer] = price;
}
else
{
emas[i][0+buffer] = emas[i-1][0+buffer]+alpha*(price -emas[i-1][0+buffer]);
emas[i][1+buffer] = emas[i-1][1+buffer]+alpha*(emas[i][0+buffer]-emas[i-1][1+buffer]);
emas[i][2+buffer] = emas[i-1][2+buffer]+alpha*(emas[i][1+buffer]-emas[i-1][2+buffer]);
emas[i][3+buffer] = emas[i-1][3+buffer]+alpha*(emas[i][2+buffer]-emas[i-1][3+buffer]);
emas[i][4+buffer] = emas[i-1][4+buffer]+alpha*(emas[i][3+buffer]-emas[i-1][4+buffer]);
emas[i][5+buffer] = emas[i-1][5+buffer]+alpha*(emas[i][4+buffer]-emas[i-1][5+buffer]);
}
return(c1*emas[i][5+buffer] + c2*emas[i][4+buffer] + c3*emas[i][3+buffer] + c4*emas[i][2+buffer]);
}
//+-------------------------------------------------------------------
//|
//+-------------------------------------------------------------------
//
//
//
//
//
void manageAlerts()
{
if (!calculateValue && alertsOn)
{
if (alertsOnCurrent)
int whichBar = 0;
else whichBar = 1; whichBar = iBarShift(NULL,0,iTime(NULL,timeFrame,whichBar));
if (UpArrow[whichBar] != EMPTY_VALUE) doAlert(whichBar,"up");
if (DnArrow[whichBar] != EMPTY_VALUE) doAlert(whichBar,"down");
}
}
//
//
//
//
//
void doAlert(int forBar, string doWhat)
{
static string previousAlert="nothing";
static datetime previousTime;
string message;
if (previousAlert != doWhat || previousTime != Time[forBar]) {
previousAlert = doWhat;
previousTime = Time[forBar];
//
//
//
//
//
message = StringConcatenate(Symbol()," at ",TimeToStr(TimeLocal(),TIME_SECONDS)," ",timeFrameToString(timeFrame)+" HAMA T3 trend changed to ",doWhat);
if (alertsMessage) Alert(message);
if (alertsEmail) SendMail(StringConcatenate(Symbol(),"HAMA T3 trend "),message);
if (alertsSound) PlaySound("alert2.wav");
}
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
//
//
//
//
//
void drawBar(int bTime, double prHigh, double prLow, double prOpen, double prClose)
{
color wickColor = ColorUp; if (prHigh >prLow) wickColor = ColorDn;
color barColor = ColorUp; if (prClose<prOpen) barColor = ColorDn;
string oName;
oName = BarsID+":"+TimeToStr(bTime)+"w";
if (ObjectFind(oName) < 0) ObjectCreate(oName,OBJ_TREND,window,bTime,0,bTime,0);
ObjectSet(oName, OBJPROP_PRICE1, prHigh);
ObjectSet(oName, OBJPROP_PRICE2, prLow);
ObjectSet(oName, OBJPROP_COLOR, wickColor);
ObjectSet(oName, OBJPROP_WIDTH, widthWick);
ObjectSet(oName, OBJPROP_RAY, false);
ObjectSet(oName, OBJPROP_BACK, true);
oName = BarsID+":"+TimeToStr(bTime)+"b";
if (ObjectFind(oName) < 0)ObjectCreate(oName,OBJ_TREND,window,bTime,0,bTime,0);
ObjectSet(oName, OBJPROP_PRICE1, prOpen);
ObjectSet(oName, OBJPROP_PRICE2, prClose);
ObjectSet(oName, OBJPROP_COLOR, barColor);
ObjectSet(oName, OBJPROP_WIDTH, widthBody);
ObjectSet(oName, OBJPROP_RAY, false);
ObjectSet(oName, OBJPROP_BACK, true);
}
//+-------------------------------------------------------------------
//|
//+-------------------------------------------------------------------
//
//
//
//
//
string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};
//
//
//
//
//
int stringToTimeFrame(string tfs)
{
tfs = stringUpperCase(tfs);
for (int i=ArraySize(iTfTable)-1; i>=0; i--)
if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
return(Period());
}
string timeFrameToString(int tf)
{
for (int i=ArraySize(iTfTable)-1; i>=0; i--)
if (tf==iTfTable[i]) return(sTfTable[i]);
return("");
}
//
//
//
//
//
string stringUpperCase(string str)
{
string s = str;
for (int length=StringLen(str)-1; length>=0; length--)
{
int char = StringGetChar(s, length);
if((char > 96 && char < 123) || (char > 223 && char < 256))
s = StringSetChar(s, length, char - 32);
else if(char > -33 && char < 0)
s = StringSetChar(s, length, char + 224);
}
return(s);
}