//+------------------------------------------------------------------+
//| Heiken Ashi Ma T3.mq4 |
//+------------------------------------------------------------------+
//| |
//| 2009 mod by mladen |
//| tools copied and pasted alerts from another HA indy so blame me |
//+------------------------------------------------------------------+
#property copyright "found and uploaded by Soixer"
#property link "http://e-sito.ru/"
#property indicator_chart_window
#property indicator_buffers 6
#property indicator_color1 Red
#property indicator_color2 RoyalBlue
#property indicator_color3 Red
#property indicator_color4 RoyalBlue
#property indicator_color5 Aqua
#property indicator_color6 Magenta
#property indicator_width1 1
#property indicator_width2 1
#property indicator_width3 2
#property indicator_width4 2
#property indicator_width5 1
#property indicator_width6 1
//
//
//
//
//
extern int MaPeriod = 10;
extern int MaMetod = 2;
extern int Step = 10;
extern bool BetterFormula = false;
extern bool T3Average = true;
extern double T3Hot = 0.618;
extern bool T3Original = false;
extern bool ShowArrows = true;
extern string _ = "Alerts settings";
extern bool Alerts.On = true;
extern bool Alerts.OnCurrent = false;
extern bool Alerts.Message = true;
extern bool Alerts.Sound = false;
extern bool Alerts.Email = false;
//
//
//
//
//
double ExtMapBuffer1[];
double ExtMapBuffer2[];
double ExtMapBuffer3[];
double ExtMapBuffer4[];
double UpArrow[];
double DnArrow[];
//
//
//
//
//
double emas[][24];
double alpha;
double c1;
double c2;
double c3;
double c4;
//+------------------------------------------------------------------+
//| |
//|------------------------------------------------------------------|
//
//
//
//
//
int init()
{
SetIndexBuffer(0, ExtMapBuffer1); SetIndexStyle(0,DRAW_HISTOGRAM);
SetIndexBuffer(1, ExtMapBuffer2); SetIndexStyle(1,DRAW_HISTOGRAM);
SetIndexBuffer(2, ExtMapBuffer3); SetIndexStyle(2,DRAW_HISTOGRAM);
SetIndexBuffer(3, ExtMapBuffer4); SetIndexStyle(3,DRAW_HISTOGRAM);
SetIndexBuffer(4, UpArrow); SetIndexArrow(4,233);
SetIndexBuffer(5, DnArrow); SetIndexStyle(5,DRAW_ARROW); SetIndexArrow(5,234);
if (ShowArrows)
{
SetIndexStyle(4,DRAW_ARROW);
SetIndexStyle(5,DRAW_ARROW);
}
else
{
SetIndexStyle(4,DRAW_NONE);
SetIndexStyle(5,DRAW_NONE);
}
//
//
//
//
//
double a = T3Hot;
c1 = -a*a*a;
c2 = 3*(a*a+a*a*a);
c3 = -3*(2*a*a+a+a*a*a);
c4 = 1+3*a+a*a*a+3*a*a;
MaPeriod = MathMax(1,MaPeriod);
if (T3Original)
alpha = 2.0/(1.0 + MaPeriod);
else alpha = 2.0/(2.0 + (MaPeriod-1.0)/2.0);
return(0);
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
//
//
//
//
//
int start()
{
double maOpen, maClose, maLow, maHigh;
double haOpen, haClose, haLow, haHigh;
int counted_bars=IndicatorCounted();
int pointModifier;
int i,limit;
//
//
//
//
//
if(counted_bars<0) return(-1);
if(counted_bars>0) counted_bars--;
limit = Bars-counted_bars;
if (ArrayRange(emas,0) != Bars) ArrayResize(emas,Bars);
if (Digits==3 || Digits==5)
pointModifier = 10;
else pointModifier = 1;
//
//
//
//
//
for(int pos=limit; pos >= 0; pos--)
{
if (T3Average)
{
maOpen = iT3(Open[pos] ,pos, 0);
maClose = iT3(Close[pos],pos, 6);
maLow = iT3(Low[pos] ,pos,12);
maHigh = iT3(High[pos] ,pos,18);
}
else
{
maOpen = iMA(NULL,0,MaPeriod,0,MaMetod,PRICE_OPEN ,pos);
maClose = iMA(NULL,0,MaPeriod,0,MaMetod,PRICE_CLOSE,pos);
maLow = iMA(NULL,0,MaPeriod,0,MaMetod,PRICE_LOW ,pos);
maHigh = iMA(NULL,0,MaPeriod,0,MaMetod,PRICE_HIGH ,pos);
}
//
//
//
//
//
if (BetterFormula) {
if (maHigh!=maLow)
haClose = (maOpen+maClose)/2+(((maClose-maOpen)/(maHigh-maLow))*MathAbs((maClose-maOpen)/2));
else haClose = (maOpen+maClose)/2; }
else haClose = (maOpen+maHigh+maLow+maClose)/4;
haOpen = (ExtMapBuffer3[pos+1]+ExtMapBuffer4[pos+1])/2;
haHigh = MathMax(maHigh, MathMax(haOpen,haClose));
haLow = MathMin(maLow, MathMin(haOpen,haClose));
if (haOpen<haClose) { ExtMapBuffer1[pos]=haLow; ExtMapBuffer2[pos]=haHigh; }
else { ExtMapBuffer1[pos]=haHigh; ExtMapBuffer2[pos]=haLow; }
ExtMapBuffer3[pos]=haOpen;
ExtMapBuffer4[pos]=haClose;
//
//
//
//
//
if (Step>0)
{
if( MathAbs(ExtMapBuffer1[pos]-ExtMapBuffer1[pos+1]) < Step*pointModifier*Point ) ExtMapBuffer1[pos]=ExtMapBuffer1[pos+1];
if( MathAbs(ExtMapBuffer2[pos]-ExtMapBuffer2[pos+1]) < Step*pointModifier*Point ) ExtMapBuffer2[pos]=ExtMapBuffer2[pos+1];
if( MathAbs(ExtMapBuffer3[pos]-ExtMapBuffer3[pos+1]) < Step*pointModifier*Point ) ExtMapBuffer3[pos]=ExtMapBuffer3[pos+1];
if( MathAbs(ExtMapBuffer4[pos]-ExtMapBuffer4[pos+1]) < Step*pointModifier*Point ) ExtMapBuffer4[pos]=ExtMapBuffer4[pos+1];
}
UpArrow[pos]=EMPTY_VALUE;
DnArrow[pos]=EMPTY_VALUE;
if (ExtMapBuffer3[pos]<ExtMapBuffer4[pos] && ExtMapBuffer4[pos+1]<ExtMapBuffer3[pos+1]) UpArrow[pos]=ExtMapBuffer4[pos+1]-(Ask-Bid);
if (ExtMapBuffer3[pos]>ExtMapBuffer4[pos] && ExtMapBuffer4[pos+1]>ExtMapBuffer3[pos+1]) DnArrow[pos]=ExtMapBuffer4[pos+1]+(Ask-Bid);
}
//
//
//
//
//
if (Alerts.On)
{
if (Alerts.OnCurrent)
int whichBar=0;
else whichBar=1;
if (UpArrow[whichBar]!= EMPTY_VALUE) doAlert("HAma buy");
if (DnArrow[whichBar]!= EMPTY_VALUE) doAlert("HAma sell");
}
return(0);
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
//
//
//
//
//
double iT3(double price,int shift,int buffer)
{
int i = Bars-shift-1;
if (i < 1)
{
emas[i][0+buffer] = price;
emas[i][1+buffer] = price;
emas[i][2+buffer] = price;
emas[i][3+buffer] = price;
emas[i][4+buffer] = price;
emas[i][5+buffer] = price;
}
else
{
emas[i][0+buffer] = emas[i-1][0+buffer]+alpha*(price -emas[i-1][0+buffer]);
emas[i][1+buffer] = emas[i-1][1+buffer]+alpha*(emas[i][0+buffer]-emas[i-1][1+buffer]);
emas[i][2+buffer] = emas[i-1][2+buffer]+alpha*(emas[i][1+buffer]-emas[i-1][2+buffer]);
emas[i][3+buffer] = emas[i-1][3+buffer]+alpha*(emas[i][2+buffer]-emas[i-1][3+buffer]);
emas[i][4+buffer] = emas[i-1][4+buffer]+alpha*(emas[i][3+buffer]-emas[i-1][4+buffer]);
emas[i][5+buffer] = emas[i-1][5+buffer]+alpha*(emas[i][4+buffer]-emas[i-1][5+buffer]);
}
return(c1*emas[i][5+buffer] + c2*emas[i][4+buffer] + c3*emas[i][3+buffer] + c4*emas[i][2+buffer]);
}
//
//
//
//
//
void doAlert(string doWhat)
{
static string previousAlert="";
static datetime previousTime=0;
string message;
if (previousAlert != doWhat || previousTime != Time[0])
{
previousAlert = doWhat;
previousTime = Time[0];
//
//
//
//
//
message = StringConcatenate(Symbol()," at ",TimeToStr(TimeLocal(),TIME_SECONDS)," Heiken ashi MA T3 : ",doWhat);
if (Alerts.Message) Alert(message);
if (Alerts.Email) SendMail(StringConcatenate(Symbol(),"Heiken ashi MA T3 "),message);
if (Alerts.Sound) PlaySound("alert2.wav");
}
}